agl-basesystem

1 files changed, 41 insertions, 0 deletions

diff --git a/bsp/meta-freescale/recipes-dpaa/fmlib/fmlib_git.bb b/bsp/meta-freescale/recipes-dpaa/fmlib/fmlib_git.bb
new file mode 100644
index 00000000..69768130
--- /dev/null
+++ b/bsp/meta-freescale/recipes-dpaa/fmlib/fmlib_git.bb
@@ -0,0 +1,41 @@
+DESCRIPTION = "Frame Manager User Space Library"
+SECTION = "fman"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=9c7bd5e45d066db084bdb3543d55b1ac"
+
+PR = "r1"
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/fmlib;nobranch=1"
+SRCREV = "82d89adae917397324c5d74108305f6c9bae8d00"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "DESTDIR=${D} PREFIX=${prefix} LIB_DEST_DIR=${libdir} \
+        CROSS_COMPILE=${TARGET_PREFIX} KERNEL_SRC=${STAGING_KERNEL_DIR}"
+
+TARGET_ARCH_FMLIB = "${DEFAULTTUNE}"
+TARGET_ARCH_FMLIB_qoriq-arm = "arm"
+TARGET_ARCH_FMLIB_qoriq-arm64 = "arm"
+TARGET_ARCH_FMLIB_e5500 = "ppc32e5500"
+TARGET_ARCH_FMLIB_e6500 = "ppc32e6500"
+TARGET_ARCH_FMLIB_e500mc = "ppce500mc"
+TARGET_ARCH_FMLIB_e500v2 = "ppce500v2"
+
+FMLIB_TARGET = "libfm-${TARGET_ARCH_FMLIB}"
+FMLIB_TARGET_t1 = "libfm-${TARGET_ARCH_FMLIB}-fmv3l"
+
+do_compile () {
+    oe_runmake ${FMLIB_TARGET}.a
+}
+
+do_install () {
+    oe_runmake install-${FMLIB_TARGET}
+}
+
+do_compile[depends] += "virtual/kernel:do_shared_workdir"
+
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+COMPATIBLE_MACHINE ?= "(qoriq)"