agl-basesystem

4 files changed, 96 insertions, 0 deletions

diff --git a/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld-rtos_git.bb b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld-rtos_git.bb
new file mode 100644
index 00000000..7f771429
--- /dev/null
+++ b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld-rtos_git.bb
@@ -0,0 +1,9 @@
+inherit ti-pdk
+
+require qmss-lld.inc
+
+PR = "${INC_PR}.1"
+
+COMPATIBLE_MACHINE_append = "|c66x"
+
+DEPENDS_append = " rm-lld-rtos"
diff --git a/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld-test_git.bb b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld-test_git.bb
new file mode 100644
index 00000000..77e698a4
--- /dev/null
+++ b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld-test_git.bb
@@ -0,0 +1,28 @@
+DESCRIPTION = "TI QMSS low level driver unit test and example binaries"
+
+DEPENDS = "common-csl-ip rm-lld cppi-lld qmss-lld cmem uio-module-drv"
+
+include qmss-lld.inc
+
+PR = "${INC_PR}.2"
+
+CHOICELIST = "yes no"
+
+do_compile () {
+#   Now build the lld in the updated directory
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" QMSS_SRC_DIR=${S}
+		for choice in ${CHOICELIST}
+		do
+			make -f makefile_armv7 tests examples PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" QMSS_SRC_DIR=${S} USEDYNAMIC_LIB="$choice"
+		done
+	done
+}
+
+do_install () {
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 installbin PDK_INSTALL_PATH=${STAGING_INCDIR} DEVICE="$device" QMSS_SRC_DIR=${S} INSTALL_BIN_BASE_DIR=${D}${bindir}
+	done
+}
diff --git a/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld.inc b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld.inc
new file mode 100644
index 00000000..d579dfa1
--- /dev/null
+++ b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld.inc
@@ -0,0 +1,27 @@
+LICENSE = "BSD-3-Clause & TI-TFL"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/ti/drv/qmss/COPYING.txt;md5=cd04fb087063a2a82c4ce61983836871"
+
+COMPATIBLE_MACHINE = "keystone"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+QMSS_LLD_GIT_URI = "git://git.ti.com/keystone-rtos/qmss-lld.git"
+QMSS_LLD_GIT_PROTOCOL = "git"
+QMSS_LLD_GIT_BRANCH = "master"
+QMSS_LLD_GIT_DESTSUFFIX = "git/ti/drv/qmss"
+
+# Below commit ID corresponding to "DEV.QMSS_LLD.02.01.00.16"
+QMSS_LLD_SRCREV = "7934ae59f545b302ede96482e61a1f79ff3518ce"
+
+BRANCH ="${QMSS_LLD_GIT_BRANCH}"
+SRC_URI = "${QMSS_LLD_GIT_URI};destsuffix=${QMSS_LLD_GIT_DESTSUFFIX};protocol=${QMSS_LLD_GIT_PROTOCOL};branch=${BRANCH}"
+SRCREV = "${QMSS_LLD_SRCREV}"
+
+PV = "02.01.00.16"
+INC_PR = "r0"
+
+DEVICELIST = "k2h k2k k2l k2e"
+DEVICELIST_k2hk = "k2h k2k"
+DEVICELIST_k2l = "k2l"
+DEVICELIST_k2e = "k2e"
+
+S = "${WORKDIR}/${QMSS_LLD_GIT_DESTSUFFIX}"
diff --git a/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld_git.bb b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld_git.bb
new file mode 100644
index 00000000..a87f4905
--- /dev/null
+++ b/bsp/meta-ti/recipes-bsp/qmss-lld/qmss-lld_git.bb
@@ -0,0 +1,32 @@
+DESCRIPTION = "TI QMSS low level driver library"
+
+DEPENDS = "common-csl-ip rm-lld"
+
+include qmss-lld.inc
+
+PR = "${INC_PR}.1"
+
+do_compile () {
+#   Now build the lld
+    make -f makefile_armv7 clean PDK_INSTALL_PATH=${STAGING_INCDIR}
+	for device in ${DEVICELIST}
+	do
+		make -f makefile_armv7 lib PDK_INSTALL_PATH=${STAGING_INCDIR}  DEVICE="${device}"
+	done
+}
+
+do_install () {
+    make -f makefile_armv7 install PDK_INSTALL_PATH=${STAGING_INCDIR} INSTALL_INC_BASE_DIR=${D}${includedir} INSTALL_LIB_BASE_DIR=${D}${libdir}
+    chown -R root:root ${D}
+
+    # Set the generic device library symbolic link to default k2h
+    cd ${D}${libdir}
+
+    # Link only the first device in the list
+    for device in ${DEVICELIST}
+    do
+        ln -sf libqmss_${device}.so.1.0.0 libqmss_device.so.1
+        break
+    done
+    ln -sf libqmss_device.so.1 libqmss_device.so
+}