2 files changed, 69 insertions, 0 deletions
diff --git a/external/meta-iot-cloud/recipes-google-cloud/google-cloud-sdk/google-cloud-sdk.inc b/external/meta-iot-cloud/recipes-google-cloud/google-cloud-sdk/google-cloud-sdk.inc
new file mode 100644
index 00000000..be187f1f
--- /dev/null
+++ b/external/meta-iot-cloud/recipes-google-cloud/google-cloud-sdk/google-cloud-sdk.inc
@@ -0,0 +1,54 @@
+RDEPENDS_${PN} = "\
+    bash \
+    python3 \
+    python3-grpcio \
+"
+
+# Default packages
+PACKAGES = "\
+    ${PN} \
+"
+
+do_compile[noexec] = "1"
+
+do_configure() {
+    # Disable updater
+    sed -i 's|"disable_updater": false|"disable_updater": true|g' ${S}/lib/googlecloudsdk/core/config.json
+}
+
+# Remove non-arch independent dependencies
+do_install_prepend() {
+    rm -rf ${S}/lib/third_party/grpc
+}
+
+do_install() {
+    install -d ${D}${bindir}
+    install -d ${D}${libdir}/${BPN}
+    install -d ${D}${sysconfdir}/bash_completion.d
+
+    install -m 0644 ${S}/completion.bash.inc ${D}${libdir}/${BPN}
+    install -m 0644 ${S}/properties ${D}${libdir}/${BPN}
+    install -m 0644 ${S}/README ${D}${libdir}/${BPN}
+    install -m 0644 ${S}/RELEASE_NOTES ${D}${libdir}/${BPN}
+    install -m 0644 ${S}/VERSION ${D}${libdir}/${BPN}
+
+    cp -r ${S}/.install ${D}${libdir}/${BPN}
+    cp -r ${S}/bin ${D}${libdir}/${BPN}
+    cp -r ${S}/data ${D}${libdir}/${BPN}
+    cp -r ${S}/lib ${D}${libdir}/${BPN}
+    cp -r ${S}/platform ${D}${libdir}/${BPN}
+
+    # Symlinks
+    ln -s ${libdir}/${BPN}/completion.bash.inc ${D}${sysconfdir}/bash_completion.d/gcloud
+    ln -s ${libdir}/${BPN}/bin/bq ${D}${bindir}/bq
+    ln -s ${libdir}/${BPN}/bin/docker-credential-gcloud ${D}${bindir}/docker-credential-gcloud
+    ln -s ${libdir}/${BPN}/bin/gcloud ${D}${bindir}/gcloud
+    ln -s ${libdir}/${BPN}/bin/git-credential-gcloud.sh ${D}${bindir}/git-credential-gcloud.sh
+    ln -s ${libdir}/${BPN}/bin/gsutil ${D}${bindir}/gsutil
+}
+
+FILES_${PN} = "\
+    ${bindir} \
+    ${libdir}/${BPN} \
+    ${sysconfdir}/bash_completion.d \
+"
diff --git a/external/meta-iot-cloud/recipes-google-cloud/google-cloud-sdk/google-cloud-sdk_277.0.0.bb b/external/meta-iot-cloud/recipes-google-cloud/google-cloud-sdk/google-cloud-sdk_277.0.0.bb
new file mode 100644
index 00000000..2341db83
--- /dev/null
+++ b/external/meta-iot-cloud/recipes-google-cloud/google-cloud-sdk/google-cloud-sdk_277.0.0.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "Command-line interface for Google Cloud Platform products and services"
+HOMEPAGE = "https://cloud.google.com/sdk/"
+AUTHOR = "Google Cloud Platform"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d02c4ee3b2a6ba87eea7b6756fd43895"
+
+SRC_URI = "https://dl.google.com/dl/cloudsdk/channels/rapid/downloads/${BPN}-${PV}-linux-x86_64.tar.gz"
+SRC_URI[md5sum] = "653aa306f499b9bf44beb52655403935"
+SRC_URI[sha256sum] = "b158894c427712d006fac235daf8d288db110ecfbcf649ed11cdf36ac2b2ff2a"
+
+PR = "r0"
+
+S = "${WORKDIR}/${BPN}"
+
+require google-cloud-sdk.inc