1 files changed, 50 insertions, 0 deletions
diff --git a/recipes-demo/hvac/hvac_git.bb b/recipes-demo/hvac/hvac_git.bb
new file mode 100644
index 00000000..2ac6a69b
--- /dev/null
+++ b/recipes-demo/hvac/hvac_git.bb
@@ -0,0 +1,50 @@
+SUMMARY     = "HVAC application"
+DESCRIPTION = "AGL demonstration HVAC application"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/hvac"
+SECTION     = "apps"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = " \
+    qttools-native \
+    qtbase \
+    qtdeclarative \
+    qtquickcontrols2 \
+    libqtappfw \
+"
+
+PV = "2.0+git${SRCPV}"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/hvac;protocol=https;branch=${AGL_BRANCH} \
+           file://hvac.conf \
+           file://hvac.token \
+"
+SRCREV = "d37674bb6dbb5ceb15c650a0344b0caf624963bc"
+
+S = "${WORKDIR}/git"
+
+inherit qmake5 pkgconfig agl-app
+
+AGL_APP_NAME = "HVAC"
+
+do_install:append() {
+    # Currently using default global client and CA certificates
+    # for KUKSA.val SSL, installing app specific ones would go here.
+
+    # VIS authorization token file for KUKSA.val should ideally not
+    # be readable by other users, but currently that's not doable
+    # until a packaging/sandboxing/MAC scheme is (re)implemented or
+    # something like OAuth is plumbed in as an alternative.
+    install -d ${D}${sysconfdir}/xdg/AGL/hvac
+    install -m 0644 ${WORKDIR}/hvac.conf ${D}${sysconfdir}/xdg/AGL/
+    install -m 0644 ${WORKDIR}/hvac.token ${D}${sysconfdir}/xdg/AGL/hvac/
+}
+
+RDEPENDS:${PN} += " \
+    qtwayland \
+    qtbase-qmlplugins \
+    qtgraphicaleffects-qmlplugins \
+    qtquickcontrols2-agl-style \
+    libqtappfw \
+"