Provide Wayland FITS, disabled by default

Wayland FITS is a functional integration test suite for
Wayland/Weston.
It consists in 2 components : a Weston plugin, and a
"wfits" binary used to run tests. The tests themselves
simulate user interaction with surfaces and windows, using
virtual keyboard/mouse/touchscreen drivers.

The recipe was recently submitted to the official
"meta-openembedded" layer, and can be found here :
http://lists.openembedded.org/pipermail/openembedded-devel/
2015-September/103511.html

The package will not be built unless the user explicitly
adds "wayland-fits" to his "conf/local.conf" file.

QEMU needs the "uinput" driver available on startup, so we
always build it, but only install it if the package has been
selected.

Change-Id: Ib6045007f6c7e1e22b48607a66930ce341c58002
Signed-off-by: Manuel Bachmann <mbc@iot.bzh>

4 files changed, 45 insertions, 0 deletions

diff --git a/meta-agl-bsp/recipes-kernel/linux/linux-yocto/uinput.cfg b/meta-agl-bsp/recipes-kernel/linux/linux-yocto/uinput.cfg
new file mode 100644
index 000000000..7996ef1dd
--- /dev/null
+++ b/meta-agl-bsp/recipes-kernel/linux/linux-yocto/uinput.cfg
@@ -0,0 +1,3 @@
+# Enable the User-level Input driver (required by "wayland-fits")
+CONFIG_INPUT_MISC=y
+CONFIG_INPUT_UINPUT=m
diff --git a/meta-agl-bsp/recipes-kernel/linux/linux-yocto_%.bbappend b/meta-agl-bsp/recipes-kernel/linux/linux-yocto_%.bbappend
new file mode 100644
index 000000000..24bd38d40
--- /dev/null
+++ b/meta-agl-bsp/recipes-kernel/linux/linux-yocto_%.bbappend
@@ -0,0 +1,4 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/linux-yocto:"
+
+# Extra configuration options for the QEMU kernel
+SRC_URI += "file://uinput.cfg"
diff --git a/meta-ivi-common/recipes-test/wayland/wayland-fits_%.bbappend b/meta-ivi-common/recipes-test/wayland/wayland-fits_%.bbappend
new file mode 100644
index 000000000..772f81b0f
--- /dev/null
+++ b/meta-ivi-common/recipes-test/wayland/wayland-fits_%.bbappend
@@ -0,0 +1,5 @@
+# Disable GTK+ and EFL tests
+PACKAGECONFIG = ""
+
+# UInput driver is necessary on QEMU
+RDEPENDS_${PN}_append_qemux86-64 = " kernel-module-uinput"
diff --git a/meta-ivi-common/recipes-test/wayland/wayland-fits_git.bb b/meta-ivi-common/recipes-test/wayland/wayland-fits_git.bb
new file mode 100644
index 000000000..3a4f8a2ca
--- /dev/null
+++ b/meta-ivi-common/recipes-test/wayland/wayland-fits_git.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Wayland-fits, the Wayland Functional Integration Test Suite"
+DESCRIPTION = "Wayland-fits is a fully automated functional integration \
+test suite. Its main purpose is to test the functionality and integration of \
+client-side (i.e. toolkit) and server-side (compositor) implementations of \
+the Wayland protocol."
+HOMEPAGE = "https://github.com/01org/wayland-fits"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=f8d34cadaf891753c0f00c6cd48f08f5 \
+                    file://src/extensions/weston/weston-wfits.cpp;endline=21;md5=848c81e55cf3a30a9f6ed75f0dba7a97"
+
+SRC_URI = "git://github.com/01org/wayland-fits.git"
+SRCREV = "f30dfa9fceb438d3687c5215093fffc21a7852fc"
+
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig
+
+DEPENDS = "libcheck boost wayland weston"
+RDEPENDS_${PN} = "weston"
+
+EXTRA_OECONF += "--enable-shared --disable-static --with-boost-libdir=${STAGING_LIBDIR}"
+
+PACKAGECONFIG ??= "elementary gtk+3"
+
+PACKAGECONFIG[elementary] = "--enable-efl-tests,--disable-efl-tests,elementary"
+PACKAGECONFIG[gtk+3] = "--enable-gtk-tests,--disable-gtk-tests,gtk+3"
+
+do_install_append() {
+	rm -f ${D}/${libdir}/weston/*.la
+}
+
+FILES_${PN} += "${bindir}/wfits ${libdir}/weston/*.so"
+FILES_${PN}-dbg += "${bindir}/.debug ${libdir}/weston/.debug ${prefix}/src"