dragonboard-410c: update 96boards-tools recipe

Update 96boards-tools recipe for dragonboard-410c.
This tool is for to resize the rootfs on the first boot.
This recipe is ported from meta-96boards layer(branch rocko).
https://github.com/96boards/meta-96boards/

Bug-AGL: SPEC-1181

Change-Id: I92372c65e0a5d65a8bdbf8ef33d8176c6039e63b
Signed-off-by: Kotaro Hashimoto <Hashimoto.Kotaro@ds.MitsubishiElectric.co.jp>

1 files changed, 32 insertions, 0 deletions

diff --git a/meta-agl-bsp/meta-qcom/recipes-bsp/96boards-tools/96boards-tools_0.11.bb b/meta-agl-bsp/meta-qcom/recipes-bsp/96boards-tools/96boards-tools_0.11.bb
new file mode 100644
index 000000000..5c3583526
--- /dev/null
+++ b/meta-agl-bsp/meta-qcom/recipes-bsp/96boards-tools/96boards-tools_0.11.bb
@@ -0,0 +1,32 @@
+SUMMARY = "Useful bits an pieces to make 96Boards more standard across the board"
+HOMEPAGE = "https://github.com/96boards/96boards-tools"
+SECTION = "devel"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
+
+SRCREV = "395b5994a5fa52f9db10f480fce74e9acdbe3318"
+SRC_URI = "git://github.com/96boards/96boards-tools;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+
+inherit systemd allarch update-rc.d
+
+do_install () {
+    install -d ${D}${sysconfdir}/udev/rules.d
+    install -m 0755 ${S}/*.rules ${D}${sysconfdir}/udev/rules.d/
+    install -d ${D}${sysconfdir}/init.d
+    install -m 0755 ${S}/resize-disk ${D}${sysconfdir}/init.d/
+
+    install -d ${D}${systemd_unitdir}/system
+    install -m 0644 ${S}/resize-helper.service ${D}${systemd_unitdir}/system
+
+    install -d ${D}${sbindir}
+    install -m 0755 ${S}/resize-helper ${D}${sbindir}
+}
+
+INITSCRIPT_NAME = "resize-disk"
+INITSCRIPT_PARAMS = "start 99 5 2 . stop 20 0 1 6 ."
+
+SYSTEMD_SERVICE_${PN} = "resize-helper.service"
+RDEPENDS_${PN} += "e2fsprogs-resize2fs gptfdisk parted util-linux udev"