Optee_os recipes modification et al.

Port of three optee patches:
- https://git.automotivelinux.org/AGL/meta-renesas-rcar-gen3/commit/?id=a9eb8fa93867b8012e0e2d520961221a2a3ffffa
- https://git.automotivelinux.org/AGL/meta-renesas-rcar-gen3/commit/?id=88d94ef02988376c22bf493e40ba339b2572236e
- https://git.automotivelinux.org/AGL/meta-renesas-rcar-gen3/commit/?id=0ba07a07e5847381c776fc07688707f1feff5a56

Bug-AGL: SPEC-3443
Change-Id: I1d49a2cf632f1f64cb66178f4899b1354b62b2a3
Signed-off-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Reviewed-on: https://gerrit.automotivelinux.org/gerrit/c/AGL/meta-agl/+/24910
Reviewed-by: Stéphane Desneux <stephane.desneux@iot.bzh>

1 files changed, 61 insertions, 0 deletions

diff --git a/meta-agl-bsp/meta-rcar-gen3/recipes-bsp/optee/optee-examples_git.bb b/meta-agl-bsp/meta-rcar-gen3/recipes-bsp/optee/optee-examples_git.bb
new file mode 100644
index 000000000..440fe8fdd
--- /dev/null
+++ b/meta-agl-bsp/meta-rcar-gen3/recipes-bsp/optee/optee-examples_git.bb
@@ -0,0 +1,61 @@
+SUMMARY = "OP-TEE examples"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=cd95ab417e23b94f381dafc453d70c30"
+
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit python3native
+
+PV = "3.6.0+git${SRCPV}"
+
+SRCREV = "292da2fd8db0176e0e96989268c63ef9ab910a6c"
+
+SRC_URI = " \
+    git://github.com/linaro-swg/optee_examples;branch=master;name=master \
+    file://0001-secure_storage-ta-Add-a-missing-include-file.patch \
+"
+
+COMPATIBLE_MACHINE = "(salvator-x|h3ulcb|m3ulcb|m3nulcb|ebisu)"
+PLATFORM = "rcar"
+
+DEPENDS = "optee-os optee-client python-pycrypto-native"
+
+CFLAGS += "-Wno-extra -Wno-error=format"
+TARGET_CFLAGS += "-Wno-extra -Wno-error=format"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+INSANE_SKIP_${PN} = "ldflags"
+
+TA_DEV_KIT_DIR = "${STAGING_DIR_TARGET}/usr/share/optee/export-ta_arm64"
+
+OPTEE_CLIENT_EXPORT = "${STAGING_DIR_TARGET}/usr"
+
+TEEC_EXPORT = "${STAGING_DIR_TARGET}/usr"
+
+S = "${WORKDIR}/git"
+EXTRA_OEMAKE = "\
+                TEEC_EXPORT=${TEEC_EXPORT} \
+                OPTEE_CLIENT_EXPORT=${OPTEE_CLIENT_EXPORT} \
+                TA_DEV_KIT_DIR=${TA_DEV_KIT_DIR} \
+                HOST_CROSS_COMPILE=${TARGET_PREFIX} \
+                TA_CROSS_COMPILE=${TARGET_PREFIX} \
+                PLATFORM=${PLATFORM} \
+                V=1 \
+                "
+
+do_compile() {
+    oe_runmake
+}
+
+do_install () {
+    mkdir -p ${D}${nonarch_base_libdir}/optee_armtz
+    mkdir -p ${D}${bindir}
+    install -D -p -m0755 ${S}/out/ca/* ${D}${bindir}
+    install -D -p -m0444 ${S}/out/ta/* ${D}${nonarch_base_libdir}/optee_armtz
+    mkdir -p ${D}${includedir}
+    cp ${S}/hello_world/ta/include/* ${D}${includedir}
+}
+
+FILES_${PN} += "${nonarch_base_libdir}/optee_armtz/"