Update to YP dunfell 3.1.5

Changes include:
- Backport gstreamer 1.16.2 vs 1.16.3 workaround for rcar3
  (originally for SPEC-3706 in master, now updated per SPEC-3803).
- Add 1.16.% wildcard version of meta-rcar-gen3-adas Kingfisher
  support layer gstreamer1.0-plugins-bad bbappend.  The issue is the
  same as with the main meta-rcar-gen3 BSP layer bbappends mentioned
  above, but this particular bbappend has been disabled in the newer
  BSP in master/koi, so they did not need a fix.
- Add override of PREFERRED_VERSION_libdrm for rcar3 to quiet
  warnings about 2.4.100 not being available, which are caused by
  dunfell 3.1.5 bringing an update to 2.4.101.
- Pin Raspberry Pi kernel version to 4.19.  meta-raspberrypi
  upstream has switched their default kernel to 5.4 on their
  dunfell branch, but that significant of a change is not desirable
  in a AGL point release.
- Remove now upstreamed systemd patch.

Bug-AGL: SPEC-3793, SPEC-3803

Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Change-Id: Ia678b8f56f35026a62a9f6ab40f9727b10756ad6
Reviewed-on: https://gerrit.automotivelinux.org/gerrit/c/AGL/meta-agl/+/26042
Tested-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Reviewed-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta-agl-bsp/meta-rcar-gen3/recipes-multimedia/gstreamer/gstreamer1.0-omx_1.16.3.bbappend b/meta-agl-bsp/meta-rcar-gen3/recipes-multimedia/gstreamer/gstreamer1.0-omx_1.16.3.bbappend
new file mode 100644
index 000000000..3f87a7539
--- /dev/null
+++ b/meta-agl-bsp/meta-rcar-gen3/recipes-multimedia/gstreamer/gstreamer1.0-omx_1.16.3.bbappend
@@ -0,0 +1,33 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}/:"
+
+SRC_URI_remove = "http://gstreamer.freedesktop.org/src/gst-omx/gst-omx-${PV}.tar.xz"
+SRC_URI_append = " \
+    gitsm://github.com/renesas-rcar/gst-omx.git;branch=RCAR-GEN3/1.16.3 \
+    file://gstomx.conf \
+"
+
+require include/rcar-gen3-path-common.inc
+
+DEPENDS += "omx-user-module mmngrbuf-user-module"
+
+SRCREV = "d9748c48c75e8c108af0300d9f452282d266ebd5"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+    file://omx/gstomx.h;beginline=1;endline=22;md5=e2c6664eda77dc22095adbed9cb6c6e4 \
+"
+
+S = "${WORKDIR}/git"
+
+GSTREAMER_1_0_OMX_TARGET = "rcar"
+GSTREAMER_1_0_OMX_CORE_NAME = "${libdir}/libomxr_core.so"
+EXTRA_OEMESON_append = " -Dheader_path=${STAGING_DIR_TARGET}/usr/local/include"
+
+do_configure_prepend() {
+    cd ${S}
+    install -m 0644 ${WORKDIR}/gstomx.conf ${S}/config/rcar/
+    sed -i 's,@RENESAS_DATADIR@,${RENESAS_DATADIR},g' ${S}/config/rcar/gstomx.conf
+    cd ${B}
+}
+
+RDEPENDS_${PN}_append = " omx-user-module"
+RDEPENDS_${PN}_remove = "libomxil"