Add weston-ivi-extension to meta-agl-profile-graphical

Add weston-ivi-extension recipe files removed from meta-agl-demo
repository to meta-agl-profile-graphical layer. This allows using
weston-ivi-extension in images other than agl-demo-platform.

Bug-AGL: SPEC-1730

Change-Id: I08a6101484ac52fc2530b61390b7bd0b1bfa8f80
Signed-off-by: Scott Murray <scott.murray@konsulko.com>

1 files changed, 32 insertions, 0 deletions

diff --git a/meta-agl-profile-graphical/recipes-graphics/wayland/wayland-ivi-extension_2.0.2.bb b/meta-agl-profile-graphical/recipes-graphics/wayland/wayland-ivi-extension_2.0.2.bb
new file mode 100644
index 000000000..1a09c7c32
--- /dev/null
+++ b/meta-agl-profile-graphical/recipes-graphics/wayland/wayland-ivi-extension_2.0.2.bb
@@ -0,0 +1,32 @@
+SUMMARY = "Wayland IVI Extension"
+DESCRIPTION = "GENIVI Layer Management API based on Wayland IVI Extension"
+HOMEPAGE = "http://projects.genivi.org/wayland-ivi-extension"
+BUGTRACKER = "http://bugs.genivi.org/enter_bug.cgi?product=Wayland%20IVI%20Extension"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=1f1a56bb2dadf5f2be8eb342acf4ed79"
+
+SRCREV = "ff067a640451de46836200624ece7ac777977c30"
+SRC_URI = "git://github.com/GENIVI/${BPN}.git;branch=2.0;protocol=http \
+        file://0001-simple-id-agent-for-2.0.2.patch \
+    "
+SRC_URI_append_wandboard = " file://wandboard_fix_build.patch"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "weston virtual/libgles2 pixman wayland-native"
+
+FILESEXTRAPATHS_prepend := ":${THISDIR}/wayland-ivi-extension:"
+
+# workaround paralellism issue:
+PARALLEL_MAKE = ""
+
+inherit cmake
+
+EXTRA_OECMAKE := "-DWITH_ILM_INPUT=1"
+
+FILES_${PN} += "${libdir}/weston/*"
+FILES_${PN} += "${datadir}/wayland-protocols/stable/ivi-application/*"
+
+FILES_${PN}-dbg += "${libdir}/weston/.debug/*"
+
+EXTRA_OECMAKE += "-DLIB_SUFFIX=${@d.getVar('baselib', True).replace('lib', '')}"