require af-binder_${PV}.inc
DEPENDS = "file json-c libmicrohttpd systemd util-linux openssl cynara"
inherit cmake pkgconfig
EXTRA_OECMAKE_append_class-target = "\
-DUNITDIR_SYSTEM=${systemd_system_unitdir} \
"
EXTRA_OECMAKE_append_agl-devel = " \
-DAGL_DEVEL=ON \
-DINCLUDE_MONITORING=ON \
-DINCLUDE_SUPERVISOR=ON -DAFS_SUPERVISION_SOCKET=/run/platform/supervisor \
"
pkg_postinst_${PN}() {
mkdir -p "$D${libdir}/afb"
}
do_install_append_agl-devel_class-target() {
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
install -d -m 0755 ${D}${systemd_system_unitdir}/multi-user.target.wants
ln -s ../afm-api-supervisor.service ${D}${systemd_system_unitdir}/multi-user.target.wants/afm-api-supervisor.service
fi
}
#############################################
# main package
#############################################
FILES_${PN}_append_agl-devel = " ${libdir}/afb/monitoring ${systemd_system_unitdir}"
RDEPENDS_${PN}-dev += "libafbwsc-dev"
#############################################
# intrinsic binding packages
#############################################
PACKAGES =+ "${PN}-intrinsic-bindings"
ALLOW_EMPTY_${PN}-intrinsic-bindings = "1"
PACKAGES_DYNAMIC = "${PN}-binding-*"
python populate_packages_prepend () {
afb_libdir = d.expand('${libdir}/afb')
postinst = d.getVar('binding_postinst', True)
pkgs = []
pkgs += do_split_packages(d, afb_libdir, '(.*)-api\.so$', d.expand('${PN}-binding-%s'), 'AFB binding for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
pkgs += do_split_packages(d, afb_libdir, '(.*(?!-api))\.so$', d.expand('${PN}-binding-%s'), 'AFB binding for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
d.setVar('RDEPENDS_' + d.getVar('PN', True) + '-intrinsic-bindings', ' '.join(pkgs))
}
#############################################
# tool package
#############################################
PACKAGES =+ "${PN}-tools"
FILES_${PN}-tools = "\
${bindir}/afb-client-demo \
"
#############################################
# setup libafbwsc package
#############################################
PACKAGES =+ "libafbwsc libafbwsc-dev"
FILES_libafbwsc = "\
${libdir}/libafbwsc.so.* \
"
FILES_libafbwsc-dev = "\
${includedir}/afb/afb-wsj1.h \
${includedir}/afb/afb-ws-client.h \
${libdir}/libafbwsc.so \
${libdir}/pkgconfig/libafbwsc.pc \
"
#############################################
# devtool package
#############################################
PACKAGES =+ "${PN}-devtools"
FILES_${PN}-devtools = "\
${bindir}/afb-exprefs \
${bindir}/afb-json2c \
${bindir}/afb-genskel \
"
#############################################
# supervisor package
#############################################
PACKAGES_append_agl-devel = " ${PN}-supervisor "
FILES_${PN}-supervisor_agl-devel = "\
${bindir}/afs-supervisor \
${systemd_system_unitdir} \
"| 2017-04-04 | dra7xx: gstreamer1.0-plugins-bad: Upgrade to 1.8.2 |   Karthik Ramanan | 11 | -0/+5140 |
| 2017-04-04 | dra7xx: gst-plugins-ti: Update VPE plugins to latest | Karthik Ramanan | 1 | -2/+2 |
| 2017-04-03 | dra7xx: gst-plugins-ti: Update ducati plugins to latest | Karthik Ramanan | 1 | -2/+2 |
| 2017-04-01 | qemux86-64: add Virtio GPU DRM driver |   Matt Porter | 1 | -0/+1 |
| 2017-03-30 | Generate weston.ini dynamically |   Ronan Le Martret | 16 | -174/+27 |
| 2017-03-30 | libuiomux: fix format security issues |   Matt Ranostay | 2 | -0/+28 |
| 2017-03-30 | dra7xx: linux: Update smack patches for Kernel 4.9 | Karthik Ramanan | 4 | -150/+0 |
| 2017-03-30 | dra7xx: Remove SRC_URI update | Karthik Ramanan | 1 | -11/+0 |
| 2017-03-30 | dra7xx: linux: rename kernel recipe to make version agnostic | Karthik Ramanan | 1 | -0/+0 |
| 2017-03-29 | dra7xx: weston: cleanup patches | Karthik Ramanan | 6 | -229/+1 |
| 2017-03-29 | dra7xx: preferred kernel is 4.9 | Karthik Ramanan | 1 | -1/+1 |
| 2017-03-29 | dra7xx: minor cleanup of config file | Karthik Ramanan | 1 | -6/+0 |
| 2017-03-29 | dra7xx: u-boot: Remove patch for compilation fix | Karthik Ramanan | 2 | -28/+2 |
| 2017-03-29 | Fix version mismatch of gstreamer for R-Car Gen3 |   Tadao Tanikawa | 2 | -0/+2 |
Yuichi Kusakabe
Jan-Simon Moeller
Harunobu Kurokawa
Ronan Le Martret
Karthik Ramanan
Matt Porter
Matt Ranostay
Tadao Tanikawa