blob: cfc465e6280f24fffe5375d22910b91319759e80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
SUMMARY = "Cross SDK of Full AGL Distribution for IVI profile"
DESCRIPTION = "SDK image for full AGL Distribution for IVI profile. \
It includes the full meta-toolchain, plus developement headers and libraries \
to form a standalone cross SDK."
require agl-image-graphical-qt5.bb
LICENSE = "MIT"
IMAGE_FEATURES_append = " dev-pkgs"
IMAGE_INSTALL_append = " kernel-dev kernel-devsrc"
inherit populate_sdk populate_sdk_qt5
# Task do_populate_sdk and do_rootfs can't be exec simultaneously.
# Both exec "createrepo" on the same directory, and so one of them
# can failed (randomly).
addtask do_populate_sdk after do_rootfs
# native tools to support Chromium build inside SDK (SPEC-942)
TOOLCHAIN_HOST_TASK += " \
nativesdk-gn \
nativesdk-ninja \
nativesdk-gperf \
nativesdk-zlib \
nativesdk-xz \
nativesdk-nspr-dev \
nativesdk-nss-dev \
nativesdk-lua \
"
# required dependencies for Chromium build inside SDK (SPEC-942)
TOOLCHAIN_TARGET_TASK += " \
pciutils-dev \
${@bb.utils.contains('DISTRO_FEATURES', 'pipewire', 'pipewire-dev wireplumber-dev', '', d)} \
cairo-dev \
nss-dev \
cups-dev \
gconf-dev \
libexif-dev \
pango-dev \
libdrm-dev \
lua-dev \
lua-staticdev \
${@bb.utils.contains('LICENSE_FLAGS_WHITELIST', 'commercial', 'ffmpeg-dev', '', d)} \
"
# Add wayland-scanner to SDK (SPEC-945)
# Use TOOLCHAIN_HOST_TASK instead of adding to the packagegroup
# wayland-scanner is in nativesdk-wayland-dev !
# option: add also nativesdk-qtwayland-tools
TOOLCHAIN_HOST_TASK_append = " nativesdk-wayland nativesdk-wayland-dev"
TOOLCHAIN_HOST_TASK_append = " nativesdk-perl-modules "
|
