diff options
| author |   Angelos Mouzakitis <a.mouzakitis@virtualopensystems.com> | 2023-10-10 14:33:42 +0000 |
|---|---|---|
| committer | Angelos Mouzakitis <a.mouzakitis@virtualopensystems.com> | 2023-10-10 14:33:42 +0000 |
| commit | af1a266670d040d2f4083ff309d732d648afba2a (patch) | |
| tree | 2fc46203448ddcc6f81546d379abfaeb323575e9 /roms/edk2/EmulatorPkg/Sec/X64 | |
| parent | e02cda008591317b1625707ff8e115a4841aa889 (diff) | |
Change-Id: Iaf8d18082d3991dec7c0ebbea540f092188eb4ec
Diffstat (limited to 'roms/edk2/EmulatorPkg/Sec/X64')
| -rw-r--r-- | roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.S | 66 | ||||
| -rw-r--r-- | roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.asm | 70 |
2 files changed, 136 insertions, 0 deletions
diff --git a/roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.S b/roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.S new file mode 100644 index 000000000..59d4e2ede --- /dev/null +++ b/roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.S @@ -0,0 +1,66 @@ +#------------------------------------------------------------------------------
+#
+# Copyright (c) 2006 - 2011, Intel Corporation. All rights reserved.<BR>
+# Portions copyright (c) 2011, Apple Inc. All rights reserved.
+# SPDX-License-Identifier: BSD-2-Clause-Patent
+#
+#------------------------------------------------------------------------------
+
+
+
+// EFI_STATUS
+// EFIAPI
+// SecTemporaryRamSupport (
+// IN CONST EFI_PEI_SERVICES **PeiServices, // %rcx
+// IN EFI_PHYSICAL_ADDRESS TemporaryMemoryBase, // %rdx
+// IN EFI_PHYSICAL_ADDRESS PermanentMemoryBase, // %r8
+// IN UINTN CopySize // %r9
+// )
+//
+ASM_GLOBAL ASM_PFX(SecTemporaryRamSupport)
+ASM_PFX(SecTemporaryRamSupport):
+ // Adjust callers %rbp to account for stack move
+ subq %rdx, %rbp // Calc offset of %rbp in Temp Memory
+ addq %r8, %rbp // add in permanent base to offset
+
+ pushq %rbp // stack frame is for the debugger
+ movq %rsp, %rbp
+
+ pushq %rdx // Save TemporaryMemoryBase
+ pushq %r8 // Save PermanentMemoryBase
+ pushq %r9 // Save CopySize
+
+ //
+ // Copy all of temp RAM to permanent memory, including stack
+ //
+ // CopyMem (PermanentMemoryBase, TemporaryMemoryBase, CopySize);
+ // %rcx, %rdx, %r8
+ movq %r8, %rcx // Shift arguments
+ movq %r9, %r8
+ subq $0x28, %rsp // Allocate register spill area & 16-byte align stack
+ call ASM_PFX(CopyMem)
+ // Temp mem stack now copied to permanent location. %esp still in temp memory
+ addq $0x28, %rsp
+
+ popq %r9 // CopySize (old stack)
+ popq %r8 // PermanentMemoryBase (old stack)
+ popq %rdx // TemporaryMemoryBase (old stack)
+
+ movq %rsp, %rcx // Move to new stack
+ subq %rdx, %rcx // Calc offset of stack in Temp Memory
+ addq %r8, %rcx // Calc PermanentMemoryBase address
+ movq %rcx, %rsp // Update stack
+ // Stack now points to permanent memory
+
+ // ZeroMem (TemporaryMemoryBase /* rcx */, CopySize /* rdx */);
+ movq %rdx, %rcx
+ movq %r9, %rdx
+ subq $0x28, %rsp // Allocate register spill area & 16-byte align stack
+ call ASM_PFX(ZeroMem)
+ addq $0x28, %rsp
+
+ // This data comes off the NEW stack
+ popq %rbp
+ ret
+
+
diff --git a/roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.asm b/roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.asm new file mode 100644 index 000000000..e66bda5bf --- /dev/null +++ b/roms/edk2/EmulatorPkg/Sec/X64/SwitchRam.asm @@ -0,0 +1,70 @@ +;------------------------------------------------------------------------------
+;
+; Copyright (c) 2006 - 2012, Intel Corporation. All rights reserved.<BR>
+; Portions copyright (c) 2011, Apple Inc. All rights reserved.
+; SPDX-License-Identifier: BSD-2-Clause-Patent
+;
+;------------------------------------------------------------------------------
+
+EXTERN CopyMem:PROC
+EXTERN ZeroMem:PROC
+
+ .code
+
+;------------------------------------------------------------------------------
+; EFI_STATUS
+; EFIAPI
+; SecTemporaryRamSupport (
+; IN CONST EFI_PEI_SERVICES **PeiServices, // %rcx
+; IN EFI_PHYSICAL_ADDRESS TemporaryMemoryBase, // %rdx
+; IN EFI_PHYSICAL_ADDRESS PermanentMemoryBase, // %r8
+; IN UINTN CopySize // %r9
+; )
+;------------------------------------------------------------------------------
+SecTemporaryRamSupport PROC
+ ; Adjust callers %rbp to account for stack move
+ sub rbp, rdx ; Calc offset of %rbp in Temp Memory
+ add rbp, r8 ; add in permanent base to offset
+
+ push rbp ; stack frame is for the debugger
+ mov rbp, rsp
+
+ push rdx ; Save TemporaryMemoryBase
+ push r8 ; Save PermanentMemoryBase
+ push r9 ; Save CopySize
+
+ ;
+ ; Copy all of temp RAM to permanent memory, including stack
+ ;
+ ; CopyMem (PermanentMemoryBase, TemporaryMemoryBase, CopySize);
+ ; %rcx, %rdx, %r8
+ mov rcx, r8 ; Shift arguments
+ mov r8, r9
+ sub rsp, 028h ; Allocate register spill area & 16-byte align stack
+ call CopyMem
+ ; Temp mem stack now copied to permanent location. %esp still in temp memory
+ add rsp, 028h
+
+ pop r9 ; CopySize (old stack)
+ pop r8 ; PermanentMemoryBase (old stack)
+ pop rdx ; TemporaryMemoryBase (old stack)
+
+ mov rcx, rsp ; Move to new stack
+ sub rcx, rdx ; Calc offset of stack in Temp Memory
+ add rcx, r8 ; Calc PermanentMemoryBase address
+ mov rsp, rcx ; Update stack
+ ; Stack now points to permanent memory
+
+ ; ZeroMem (TemporaryMemoryBase /* rcx */, CopySize /* rdx */);
+ mov rcx, rdx
+ mov rdx, r9
+ sub rsp, 028h ; Allocate register spill area & 16-byte align stack
+ call ZeroMem
+ add rsp, 028h
+
+ ; This data comes off the NEW stack
+ pop rbp
+ ret
+SecTemporaryRamSupport ENDP
+
+ END
|