4 files changed, 140 insertions, 0 deletions
diff --git a/roms/edk2/ArmPkg/Library/ArmSvcLib/AArch64/ArmSvc.S b/roms/edk2/ArmPkg/Library/ArmSvcLib/AArch64/ArmSvc.S
new file mode 100644
index 000000000..ee265f94b
--- /dev/null
+++ b/roms/edk2/ArmPkg/Library/ArmSvcLib/AArch64/ArmSvc.S
@@ -0,0 +1,43 @@
+//
+//  Copyright (c) 2012 - 2020, ARM Limited. All rights reserved.
+//
+//  SPDX-License-Identifier: BSD-2-Clause-Patent
+//
+//
+
+.text
+.align 3
+
+GCC_ASM_EXPORT(ArmCallSvc)
+
+ASM_PFX(ArmCallSvc):
+  // Push frame pointer and return address on the stack
+  stp   x29, x30, [sp, #-32]!
+  mov   x29, sp
+
+  // Push x0 on the stack - The stack must always be quad-word aligned
+  str   x0, [sp, #16]
+
+  // Load the SVC arguments values into the appropriate registers
+  ldp   x6, x7, [x0, #48]
+  ldp   x4, x5, [x0, #32]
+  ldp   x2, x3, [x0, #16]
+  ldp   x0, x1, [x0, #0]
+
+  svc   #0
+  // Prevent speculative execution beyond svc instruction
+  dsb   nsh
+  isb
+
+  // Pop the ARM_SVC_ARGS structure address from the stack into x9
+  ldr   x9, [sp, #16]
+
+  // Store the SVC returned values into the ARM_SVC_ARGS structure.
+  // A SVC call can return up to 4 values - we do not need to store back x4-x7.
+  stp   x0, x1, [x9, #0]
+  stp   x2, x3, [x9, #16]
+
+  mov   x0, x9
+
+  ldp   x29, x30, [sp], #32
+  ret
diff --git a/roms/edk2/ArmPkg/Library/ArmSvcLib/Arm/ArmSvc.S b/roms/edk2/ArmPkg/Library/ArmSvcLib/Arm/ArmSvc.S
new file mode 100644
index 000000000..e81eb88f2
--- /dev/null
+++ b/roms/edk2/ArmPkg/Library/ArmSvcLib/Arm/ArmSvc.S
@@ -0,0 +1,36 @@
+//
+//  Copyright (c) 2016 - 2020, ARM Limited. All rights reserved.
+//
+//  SPDX-License-Identifier: BSD-2-Clause-Patent
+//
+//
+
+.text
+.align 3
+
+GCC_ASM_EXPORT(ArmCallSvc)
+
+ASM_PFX(ArmCallSvc):
+    // r0 will be popped just after the SVC call
+    push    {r0, r4-r8}
+
+    // Load the SVC arguments values into the appropriate registers
+    ldm     r0, {r0-r7}
+
+    svc     #0
+    // Prevent speculative execution beyond svc instruction
+    dsb     nsh
+    isb
+
+    // Load the ARM_SVC_ARGS structure address from the stack into r8
+    ldr     r8, [sp]
+
+    // Load the SVC returned values into the appropriate registers
+    // A SVC call can return up to 4 values - we do not need to store back r4-r7.
+    stm     r8, {r0-r3}
+
+    mov     r0, r8
+
+    // Restore the registers r4-r8
+    pop     {r1, r4-r8}
+    bx      lr
diff --git a/roms/edk2/ArmPkg/Library/ArmSvcLib/Arm/ArmSvc.asm b/roms/edk2/ArmPkg/Library/ArmSvcLib/Arm/ArmSvc.asm
new file mode 100644
index 000000000..d1751488b
--- /dev/null
+++ b/roms/edk2/ArmPkg/Library/ArmSvcLib/Arm/ArmSvc.asm
@@ -0,0 +1,36 @@
+//
+//  Copyright (c) 2016 - 2020, ARM Limited. All rights reserved.
+//
+//  SPDX-License-Identifier: BSD-2-Clause-Patent
+//
+//
+
+
+    INCLUDE AsmMacroExport.inc
+
+ RVCT_ASM_EXPORT ArmCallSvc
+    // r0 will be popped just after the SVC call
+    push     {r0, r4-r8}
+
+    // Load the SVC arguments values into the appropriate registers
+    ldm     r0, {r0-r7}
+
+    svc     #0
+    // Prevent speculative execution beyond svc instruction
+    dsb     nsh
+    isb
+
+    // Load the ARM_SVC_ARGS structure address from the stack into r8
+    ldr     r8, [sp]
+
+    // Load the SVC returned values into the appropriate registers
+    // A SVC call can return up to 4 values - we do not need to store back r4-r7.
+    stm     r8, {r0-r3}
+
+    mov     r0, r8
+
+    // Restore the registers r4-r8
+    pop     {r1, r4-r8}
+    bx      lr
+
+    END
diff --git a/roms/edk2/ArmPkg/Library/ArmSvcLib/ArmSvcLib.inf b/roms/edk2/ArmPkg/Library/ArmSvcLib/ArmSvcLib.inf
new file mode 100644
index 000000000..744a29fbf
--- /dev/null
+++ b/roms/edk2/ArmPkg/Library/ArmSvcLib/ArmSvcLib.inf
@@ -0,0 +1,25 @@
+#/** @file
+#
+#  Copyright (c) 2016 - 2017, ARM Ltd. All rights reserved.<BR>
+#  SPDX-License-Identifier: BSD-2-Clause-Patent
+#
+#**/
+
+[Defines]
+  INF_VERSION                    = 0x0001001A
+  BASE_NAME                      = ArmSvcLib
+  FILE_GUID                      = 8e3618d7-f01d-4d65-b32b-4c70aacc8e49
+  MODULE_TYPE                    = BASE
+  VERSION_STRING                 = 1.0
+  LIBRARY_CLASS                  = ArmSvcLib
+
+[Sources.ARM]
+  Arm/ArmSvc.asm    | RVCT
+  Arm/ArmSvc.S      | GCC
+
+[Sources.AARCH64]
+  AArch64/ArmSvc.S
+
+[Packages]
+  ArmPkg/ArmPkg.dec
+  MdePkg/MdePkg.dec