1 files changed, 60 insertions, 0 deletions
diff --git a/roms/edk2/MdePkg/Library/BaseLib/Ia32/LongJump.nasm b/roms/edk2/MdePkg/Library/BaseLib/Ia32/LongJump.nasm
new file mode 100644
index 000000000..f94d10f80
--- /dev/null
+++ b/roms/edk2/MdePkg/Library/BaseLib/Ia32/LongJump.nasm
@@ -0,0 +1,60 @@
+;------------------------------------------------------------------------------
+;
+; Copyright (c) 2006 - 2019, Intel Corporation. All rights reserved.<BR>
+; SPDX-License-Identifier: BSD-2-Clause-Patent
+;
+; Module Name:
+;
+;   LongJump.Asm
+;
+; Abstract:
+;
+;   Implementation of _LongJump() on IA-32.
+;
+;------------------------------------------------------------------------------
+
+%include "Nasm.inc"
+
+    SECTION .text
+
+extern ASM_PFX(PcdGet32 (PcdControlFlowEnforcementPropertyMask))
+
+;------------------------------------------------------------------------------
+; VOID
+; EFIAPI
+; InternalLongJump (
+;   IN      BASE_LIBRARY_JUMP_BUFFER  *JumpBuffer,
+;   IN      UINTN                     Value
+;   );
+;------------------------------------------------------------------------------
+global ASM_PFX(InternalLongJump)
+ASM_PFX(InternalLongJump):
+
+    mov     eax, [ASM_PFX(PcdGet32 (PcdControlFlowEnforcementPropertyMask))]
+    test    eax, eax
+    jz      CetDone
+    mov     eax, cr4
+    bt      eax, 23                ; check if CET is enabled
+    jnc     CetDone
+
+    mov     edx, [esp + 4]         ; edx = JumpBuffer
+    mov     edx, [edx + 24]        ; edx = target SSP
+    READSSP_EAX
+    sub     edx, eax               ; edx = delta
+    mov     eax, edx               ; eax = delta
+
+    shr     eax, 2                 ; eax = delta/sizeof(UINT32)
+    INCSSP_EAX
+
+CetDone:
+
+    pop     eax                         ; skip return address
+    pop     edx                         ; edx <- JumpBuffer
+    pop     eax                         ; eax <- Value
+    mov     ebx, [edx]
+    mov     esi, [edx + 4]
+    mov     edi, [edx + 8]
+    mov     ebp, [edx + 12]
+    mov     esp, [edx + 16]
+    jmp     dword [edx + 20]        ; restore "eip"
+